Program that autoboot to data disc mode?

SDK Get Help
1

Has anyone made a program that autoboots the playdate into data disc mode then copies over files and exits disc mode?
I was asuming since the sim can do this from a pc its prorbubly just a serial comand u can send?

I was looking for a faster way than using the sideload option on the website.

I know there were some external storefronts, dono if they had a solution for this?

It would also make it easier to manage games on a new playdate in some ways
When I got my second device I just installed the games I wanted and overnight it installed all the rest from my sideload page.
If we installed them like it's sent from the simulator it wouldn't have done that.

Also gives a simpler way of creating physical releases of games.

2
  • i made a simple bat script that copies over files once the playdate is already in disc mode just need to add whatever triggers the playdate to boot into disc mode in the first place. and in an ideal world unmount once its copied too.
    the playdate sim allows for mount and unmount so i assume we can too?
3

Since you mentioned batch I assume you're on Windows. In that case, you'll find the Playdate as a serial device on one of your COM ports. Send the text datadisk, plus a CRLF, to reboot into the data disk.

4

yip on windows
oh thanks , yip i saw it was connected on com5 just dint know what to do with it. I watched the simulator output when connecting and disconnecting but didn't show the command.
I will try and get back

5

that worked great thanks
Had to add a timeout as it was trying to copy before the disc was ready.
timeout /t 7 > nul

The las thig would be to get it to eject. tried a couple of ways for this withought needing windows admin. for now il just say press "a" on playdate

6 
@echo off
setlocal

rem Set the command to send
set "command=datadisk"

rem Set the COM port number
set "comport=COM5"

rem Create a temporary script file
set "temp_script=%temp%\temp_script.txt"
echo %command% > "%temp_script%"
echo. >> "%temp_script%"
echo. >> "%temp_script%"

rem Use the COPY command to send the text to the COM port
copy "%temp_script%" %comport% > nul

rem Clean up the temporary script file
del "%temp_script%"

echo Command sent successfully to %comport%
echo Waiting for playdate...
timeout /t 7 > nul

rem Set source folder path relative to the batch file's directory
set "source_folder=%~dp0Filestocopy"
set "destination_folder=G:\Games"

echo Copying files from "%source_folder%" to "%destination_folder%"...

if not exist "%destination_folder%" (
    mkdir "%destination_folder%"
)

xcopy /s /y "%source_folder%\*" "%destination_folder%"

echo Files copied successfully. Press A button on playdate and your game should be installed.

pause

right now this assumes ur playdate is on drive G and com port 5